XML

XML-vormingus andmete näide

<?xml version='1.0'?> 
<RAAMATUD>
  <RAAMAT>
    <PEALKIRI>Kevade</PEALKIRI>
    <AUTOR>Oskar Luts</AUTOR>
  </RAAMAT>
  <RAAMAT>
    <PEALKIRI>Sipsik</PEALKIRI>
    <AUTOR>Eno Raud</AUTOR>
  </RAAMAT>
  <RAAMAT>
    <PEALKIRI>Bullerby Lapsed</PEALKIRI>
    <AUTOR>Astrid Lindgren</AUTOR>
  </RAAMAT>
</RAAMATUD>


Andmete lugemiseks kasutatav kood

Sub loeXML()
  Set XMLDoc = CreateObject("MSXML.DomDocument")
  XMLDoc.Load "c:\raamatud1.xml" 'failinimi
  Debug.Print "Teise raamatu pealkiri: " & _
                 XMLDoc.documentElement.childNodes(1).childNodes(0).Text
 Set teineRaamat = XMLDoc.documentElement.childNodes(1)
 Set esimeneRaamat = teineRaamat.previousSibling
 Set esimeseRaamatuAutor = esimeneRaamat.childNodes(1)
 Debug.Print "<br>Esimese autor: " & esimeseRaamatuAutor.Text & _
                "<br> Raamatuid kokku: " & _ 
                      esimeneRaamat.parentNode.childNodes.Length

 Set autorid = XMLDoc.getElementsByTagName("AUTOR")
 Debug.Print "<br>Autoreid on " & autorid.Length & _
    ", neist esimene " & autorid(0).Text
 Debug.Print "<br>Kokku on elemente " & XMLDoc.getElementsByTagName("*").Length
 Debug.Print "<br>Teise raamatu autor on " & _ 
    teineRaamat.selectSingleNode("AUTOR").Text
End Sub

XML-dokumendi loomine mälus.

Sub teeXML()
  Set xmldoc = CreateObject("MSXML.DomDocument")
  Set juur = xmldoc.createNode(1, "eesnimed", "") '1 tähendab lehte
  xmldoc.documentelement = juur
  Set nimeelement = xmldoc.createNode(1, "eesnimi", "")
  nimeelement.Text = "Juku"
  xmldoc.documentelement.appendChild nimeelement
  Set nimeelement = xmldoc.createNode(1, "eesnimi", "")
  nimeelement.Text = "Kati"
  xmldoc.documentelement.appendChild nimeelement
  Set nimeelement = xmldoc.createNode(1, "eesnimi", "")
  nimeelement.Text = "Mati"
  xmldoc.documentelement.appendChild nimeelement
  MsgBox xmldoc.xml
End Sub

Andmebaasiühendus

Sub kysimine1()
  Dim cn As New ADODB.Connection
  Dim rs As ADODB.Recordset
  Dim lause As String
  cn.Open "yhendus1"
  lause = "SELECT eesnimi FROM inimesed " & _
             "ORDER BY eesnimi DESC"
  Set rs = cn.Execute(lause)
  Do While Not rs.EOF
    MsgBox rs("eesnimi")
    rs.MoveNext
  Loop
  cn.Close
End Sub


Sub lisamine1()
  Dim cn As New Connection
  Dim lause As String
  cn.Open "yhendus1"
  lause = "INSERT INTO inimesed (eesnimi, perekonnanimi) " & _
    "VALUES ('Siim', 'Tamm')"
  cn.Execute lause
  cn.Close
End Sub

Sub lisamine2()
  Dim cn As New Connection
  Dim cm As New Command
  Dim lause As String
  cn.Open "yhendus1"
  lause = "INSERT INTO inimesed (eesnimi, perekonnanimi) " & _
    "VALUES (?, ?)"
  Set cm.ActiveConnection = cn
  cm.CommandText = lause
  cm.CommandType = adCmdText
  cm.Parameters.Append cm.CreateParameter("eesnimi", adVarChar, adParamInput, 50)
  cm.Parameters.Append cm.CreateParameter("perekonnanimi", adVarChar, adParamInput, 50)
  cm.Parameters("eesnimi").Value = "Leena"
  cm.Parameters("perekonnanimi").Value = "Ivask"
  cm.Execute
  cm.Parameters("eesnimi").Value = "Mart"
  cm.Parameters("perekonnanimi").Value = "Kask"
  cm.Execute
  cn.Close
End Sub

Sub lisamine3()
  Dim cn As New Connection
  Dim cm As New Command
  Dim lause As String
  cn.Open "yhendus1"
  uenimi = InputBox("Palun eesnimi")
  upnimi = InputBox("Palun perekonnanimi")
  lause = "INSERT INTO inimesed (eesnimi, perekonnanimi) " & _
    "VALUES ('" & uenimi & "', '" & upnimi & "')"
  MsgBox lause
  cn.Execute lause
  cn.Close
End Sub