package{
  import flash.display.Sprite;
  import flash.events.*;
  public class Spiraal3 extends Sprite{
     private var algRaadius:Number=100;
	 private var kahanemisKoef:Number=0.7; //Kahanemissuhe ringi kohta
	 private var minRaadius:Number=0.3;
	 private var liikumisKoef:Number=1.05;
     public function Spiraal3(){
	   joonista();
	   y=150;
	   addEventListener(Event.ENTER_FRAME, liigu);
	 }

     public function joonista():void{
	   graphics.clear();
	   graphics.lineStyle(0.5, 0, 1); //paksus, värv, nähtavus
	   var raadius:Number=algRaadius;
	   var nurk:Number=0;
	   var sektoriteArv:Number=100;
	   var raadiusKoef:Number=Math.pow(kahanemisKoef, 1/sektoriteArv);
	   var dNurk:Number=2*Math.PI/sektoriteArv;
	   graphics.moveTo(raadius, 0);
	   while(raadius>minRaadius){
		  graphics.lineTo(raadius*Math.cos(nurk), raadius*Math.sin(nurk));
		  raadius*=raadiusKoef;
		  nurk+=dNurk;
	   }
	 }
	 public function liigu(e:Event):void{
		scaleX*=liikumisKoef;
		scaleY*=liikumisKoef;
		if(scaleX>10){
		  scaleX*=kahanemisKoef;
		  scaleY*=kahanemisKoef;
		} 
     }
  }
}